1С удалила предопределенные наборы свойств

После обновления 1С у клиента начала возникать ошибка:

Полный текст ошибки тут.
Поле объекта не обнаружено (Справочник_Организации)
{ВнешняяОбработка.АктСверкиДвиженияИОстатковМатериальныхЦенностей.Форма.Форма.Форма(272)}:НаборДополнительныхРеквизитовКонтрагента = Справочники.НаборыДополнительныхРеквизитовИСведений[НаборСвойствСтрокой].ПолучитьОбъект(); //Справочник_Контрагенты
{ВнешняяОбработка.АктСверкиДвиженияИОстатковМатериальныхЦенностей.Форма.Форма.Форма(231)}:Реквизит = СоздатьДопРеквизитНаСервере(НаборСвойствСтрокой, ИдентификаторРеквизита, НаименованиеРеквизита, ТипЗначения, Многострочный);
{ВнешняяОбработка.АктСверкиДвиженияИОстатковМатериальныхЦенностей.Форма.Форма.Форма(22)}:ДатьЗначениеДопРеквизитаНаСервере(Объект.Организация, "ДолжностьРуководителяОрганизации", "Должность руководителя организации", ТипСтрока1024()));
{ВнешняяОбработка.АктСверкиДвиженияИОстатковМатериальныхЦенностей.Форма.Форма.Форма(204)}:СформироватьНаСервере();

[ОшибкаВоВремяВыполненияВстроенногоЯзыка, ОшибкаИспользованияВстроенногоЯзыка]

В справочнике НаборыДополнительныхРеквизитовИСведений 1С устроила тотальный погром:

Код был таким:

Функция  ДатьЗначениеДопРеквизитаНаСервере(Ссылка, ИдентификаторРеквизита, НаименованиеРеквизита, ТипЗначения = Неопределено, Многострочный = 0) Экспорт
	Если ТипЗнч(Ссылка) = Тип("СправочникСсылка.Контрагенты") Тогда
		НаборСвойствСтрокой = "Справочник_Контрагенты";
	//ИначеЕсли ТипЗнч(Ссылка) = Тип("СправочникСсылка.Партнеры") Тогда
	//	НаборСвойствСтрокой = "Справочник_Партнеры_Общие";
	ИначеЕсли ТипЗнч(Ссылка) = Тип("СправочникСсылка.Организации") Тогда
		НаборСвойствСтрокой = "Справочник_Организации";
	ИначеЕсли ТипЗнч(Ссылка) = Тип("СправочникСсылка.Склады") Тогда
		НаборСвойствСтрокой = "Справочник_Склады";
	//ИначеЕсли ТипЗнч(Ссылка) = Тип("СправочникСсылка.ДоговорыКонтрагентов") Тогда
	//	НаборСвойствСтрокой = "Справочник_ДоговорыКонтрагентов";
	//ИначеЕсли ТипЗнч(Ссылка) = Тип("ДокументСсылка.ЗаказКлиента") Тогда
	//	НаборСвойствСтрокой = "Документ_ЗаказКлиента";
	Иначе
		Возврат Неопределено;
	КонецЕсли;
	УстановитьПривилегированныйРежим(Истина);
	Реквизит = СоздатьДопРеквизитНаСервере(НаборСвойствСтрокой, ИдентификаторРеквизита, НаименованиеРеквизита, ТипЗначения, Многострочный);
	ИскСтрока = Ссылка.ДополнительныеРеквизиты.Найти(Реквизит, "Свойство");
	Если ИскСтрока = Неопределено Тогда
		Возврат Неопределено;
	КонецЕсли;
	Возврат ИскСтрока.Значение;
КонецФункции

&НаСервере
Функция СоздатьДопРеквизитНаСервере(НаборСвойствСтрокой, ИдентификаторРеквизита, НаименованиеРеквизита, ТипЗначения = Неопределено, Многострочный = 0) Экспорт
	УстановитьПривилегированныйРежим(Истина);
	
    //включим константу использования
    Если Не Константы.ИспользоватьДополнительныеРеквизитыИСведения.Получить() Тогда
        Константы.ИспользоватьДополнительныеРеквизитыИСведения.Установить(Истина);
    КонецЕсли;
	
	//попробуем найти реквизит по наименованию
	//ДопРеквизитСсылка = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоНаименованию(ИмяРеквизита);
	ДопРеквизитСсылка = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоРеквизиту("Имя", ИдентификаторРеквизита);
	Если НЕ ЗначениеЗаполнено(ДопРеквизитСсылка) Тогда
		//если не нашли реквизит - будем его создавать
		ДопРеквизитОбъект = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.СоздатьЭлемент();
		ДопРеквизитОбъект.Заголовок = НаименованиеРеквизита;
		ДопРеквизитОбъект.НаборСвойств = Справочники.НаборыДополнительныхРеквизитовИСведений[НаборСвойствСтрокой]; //.Справочник_Контрагенты;
		Если ТипЗначения = Неопределено Тогда
			ТипЗначения = Новый ОписаниеТипов("Строка",,,,Новый КвалификаторыСтроки(250));
		КонецЕсли;
        ДопРеквизитОбъект.ТипЗначения = ТипЗначения; //
		ДопРеквизитОбъект.Наименование = ДопРеквизитОбъект.Заголовок + " ("+ДопРеквизитОбъект.НаборСвойств+")";
		ДопРеквизитОбъект.Виден = Истина;
		ДопРеквизитОбъект.Доступен = Истина;
		ДопРеквизитОбъект.МногострочноеПолеВвода = Многострочный;
		ДопРеквизитОбъект.ДополнительныеЗначенияИспользуются = Истина;
		//зададим имя нового реквизита
		ДопРеквизитОбъект.Имя = ИдентификаторРеквизита; //"filap_"+СтрЗаменить(ИмяРеквизита," ","");
		ДопРеквизитОбъект.Записать();
		ДопРеквизитСсылка = ДопРеквизитОбъект.Ссылка;		
	КонецЕсли;
	
    //добавим наш реквизит в набор дополнительных реквизитов контрагента
    НаборДополнительныхРеквизитовКонтрагента = Справочники.НаборыДополнительныхРеквизитовИСведений[НаборСвойствСтрокой].ПолучитьОбъект(); //Справочник_Контрагенты
    Если НаборДополнительныхРеквизитовКонтрагента.ДополнительныеРеквизиты.Найти(ДопРеквизитСсылка, "Свойство") = Неопределено Тогда
        //добавим реквизит в набор
        Стр = НаборДополнительныхРеквизитовКонтрагента.ДополнительныеРеквизиты.Добавить();
        Стр.Свойство = ДопРеквизитСсылка;
		НаборДополнительныхРеквизитовКонтрагента.Записать();
    КонецЕсли;
	
	Возврат  ДопРеквизитСсылка;
КонецФункции

Предопределенные элементы удалены. В модуле менеджера ничего на замену им нет (или я не нашел). Приходится ориентироваться на названия элементов, увы. 1С продолжает радовать нас хитрыми подходами к архитектуре, делая жизнь программистов все сложнее.

После исправления код стал выглядеть так (сделал поиск свойства по наименованию и сделал его вызов один раз, а не два, добавил исключение если не найден):

Функция  ДатьЗначениеДопРеквизитаНаСервере(Ссылка, ИдентификаторРеквизита, НаименованиеРеквизита, ТипЗначения = Неопределено, Многострочный = 0) Экспорт
	Если ТипЗнч(Ссылка) = Тип("СправочникСсылка.Контрагенты") Тогда
		НаборСвойствСтрокой = "Контрагенты"; //2026-11 исправление
	//ИначеЕсли ТипЗнч(Ссылка) = Тип("СправочникСсылка.Партнеры") Тогда
	//	НаборСвойствСтрокой = "Справочник_Партнеры_Общие";
	ИначеЕсли ТипЗнч(Ссылка) = Тип("СправочникСсылка.Организации") Тогда
		НаборСвойствСтрокой = "Организации"; //2026-11 исправление
	ИначеЕсли ТипЗнч(Ссылка) = Тип("СправочникСсылка.Склады") Тогда
		НаборСвойствСтрокой = "Склады"; //2026-11 исправление
		//ИначеЕсли ТипЗнч(Ссылка) = Тип("СправочникСсылка.ДоговорыКонтрагентов") Тогда
	//	НаборСвойствСтрокой = "Справочник_ДоговорыКонтрагентов";
	//ИначеЕсли ТипЗнч(Ссылка) = Тип("ДокументСсылка.ЗаказКлиента") Тогда
	//	НаборСвойствСтрокой = "Документ_ЗаказКлиента";
	Иначе
		Возврат Неопределено;
	КонецЕсли;
	УстановитьПривилегированныйРежим(Истина);
	Реквизит = СоздатьДопРеквизитНаСервере(НаборСвойствСтрокой, ИдентификаторРеквизита, НаименованиеРеквизита, ТипЗначения, Многострочный);
	ИскСтрока = Ссылка.ДополнительныеРеквизиты.Найти(Реквизит, "Свойство");
	Если ИскСтрока = Неопределено Тогда
		Возврат Неопределено;
	КонецЕсли;
	Возврат ИскСтрока.Значение;
КонецФункции

&НаСервере
Функция СоздатьДопРеквизитНаСервере(НаборСвойствСтрокой, ИдентификаторРеквизита, НаименованиеРеквизита, ТипЗначения = Неопределено, Многострочный = 0) Экспорт
	УстановитьПривилегированныйРежим(Истина);
	
    //включим константу использования
    Если Не Константы.ИспользоватьДополнительныеРеквизитыИСведения.Получить() Тогда
        Константы.ИспользоватьДополнительныеРеквизитыИСведения.Установить(Истина);
    КонецЕсли;
	
	//попробуем найти реквизит по наименованию
	//ДопРеквизитСсылка = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоНаименованию(ИмяРеквизита);
	ДопРеквизитСсылка = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.НайтиПоРеквизиту("Имя", ИдентификаторРеквизита);
	НаборСвойствСсылка = Справочники.НаборыДополнительныхРеквизитовИСведений.НайтиПоНаименованию(НаборСвойствСтрокой); //2026-11 исправление 
	Если нЕ ЗначениеЗаполнено(НаборСвойствСсылка) Тогда
		ВызватьИсключение "Не найден набор свойств с названием: " + НаборСвойствСтрокой;
	КонецЕсли;
	Если НЕ ЗначениеЗаполнено(ДопРеквизитСсылка) Тогда
		//если не нашли реквизит - будем его создавать
		ДопРеквизитОбъект = ПланыВидовХарактеристик.ДополнительныеРеквизитыИСведения.СоздатьЭлемент();
		ДопРеквизитОбъект.Заголовок = НаименованиеРеквизита;
		ДопРеквизитОбъект.НаборСвойств = НаборСвойствСсылка; //.Контрагенты; //2026-11 исправление
		Если ТипЗначения = Неопределено Тогда
			ТипЗначения = Новый ОписаниеТипов("Строка",,,,Новый КвалификаторыСтроки(250));
		КонецЕсли;
        ДопРеквизитОбъект.ТипЗначения = ТипЗначения; //
		ДопРеквизитОбъект.Наименование = ДопРеквизитОбъект.Заголовок + " ("+ДопРеквизитОбъект.НаборСвойств+")";
		ДопРеквизитОбъект.Виден = Истина;
		ДопРеквизитОбъект.Доступен = Истина;
		ДопРеквизитОбъект.МногострочноеПолеВвода = Многострочный;
		ДопРеквизитОбъект.ДополнительныеЗначенияИспользуются = Истина;
		//зададим имя нового реквизита
		ДопРеквизитОбъект.Имя = ИдентификаторРеквизита; //"filap_"+СтрЗаменить(ИмяРеквизита," ","");
		ДопРеквизитОбъект.Записать();
		ДопРеквизитСсылка = ДопРеквизитОбъект.Ссылка;		
	КонецЕсли;
	
    //добавим наш реквизит в набор дополнительных реквизитов контрагента
    НаборДополнительныхРеквизитовКонтрагента = НаборСвойствСсылка.ПолучитьОбъект(); //Справочник_Контрагенты       //2026-11 исправление
    Если НаборДополнительныхРеквизитовКонтрагента.ДополнительныеРеквизиты.Найти(ДопРеквизитСсылка, "Свойство") = Неопределено Тогда
        //добавим реквизит в набор
        Стр = НаборДополнительныхРеквизитовКонтрагента.ДополнительныеРеквизиты.Добавить();
        Стр.Свойство = ДопРеквизитСсылка;
		НаборДополнительныхРеквизитовКонтрагента.Записать();
    КонецЕсли;
	
	Возврат  ДопРеквизитСсылка;
КонецФункции

Увы, 1С не радует своих программистов стабильностью и надежностей. А пользователи попадают на лишние затраты по сопровождению доработок.

Среда: БП 3.0.210.11 Объем: 0.5 час

image_pdfimage_print

fixin

Программирую на 1С с 1999 года. В 1С просто Гений. В 2020 году ушел из офиса на вольные хлеба фриланса. Принимаю заказы.

Вам может также понравиться...

Добавить комментарий

Ваш адрес email не будет опубликован. Обязательные поля помечены *