Альтернативный способ доработки типовых печатных форм. БСП

Всем известен способ доработки типовой печатной формы, когда ее код копируется в модуль обработки. Конечно, 1С плохо изолирует функции и там приходится немного повозиться, но ничего сложного. Например, тут описана последовательность.

Недостаток — нужно отслеживать изменения в типовом макете и алгоритмах. Можно, конечно, дергать типовой макет, но иногда 1С и код по выбору макета берет меняет, например, если печатная форма зависит от даты документа.

А если нужно всего-лишь поменять название номенклатуры? Зачем эти сложности.

Можно просто в своей печатной форме вызвать типовую печатную форму. Например так:

Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт
	
	ПараметрыВывода.ДоступнаПечатьПоКомплектно = Истина;
	
	Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, СтруктураМакета.Идентификатор) Тогда
		
		ПараметрыПечати = Новый Структура(); //»ДополнитьКомплектВнешнимиПечатнымиФормами» = ложь
    	ДопустимыеТипыОбъектовПечати = Неопределено;
		
		ИмяМенеджераПечати = "Документ.РасходнаяНакладная";
        ИменаМакетов = "Обработка.ПечатьСчетФактура.УниверсальныйПередаточныйДокумент";
		
		ПечатныеФормы = УправлениеПечатью.СформироватьПечатныеФормы(ИмяМенеджераПечати, ИменаМакетов, МассивОбъектов, ПараметрыПечати, ДопустимыеТипыОбъектовПечати);
    	ПодготовленныйТабДок = ПечатныеФормы.КоллекцияПечатныхФорм[0].ТабличныйДокумент;	
		
		ОбработатьТабДок(МассивОбъектов[0], ПодготовленныйТабДок);
	
		УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, СтруктураМакета.Идентификатор, СтруктураМакета.Представление, ПодготовленныйТабДок); 
		
	КонецЕсли;
	
	КоллекцияПечатныхФорм[0].ТабличныйДокумент = ПодготовленныйТабДок;     
	
КонецПроцедуры

А далее при получении данных для печати формы, просто определить, работаем ли мы из своей внешней печатной формы, и если да, то сделать нужные замены.

Вот код по замене данных в модуле менеджера расходной накладной:

&Вместо("ДанныеДокументовРегУчет")
Функция Доп_ДанныеДокументовРегУчет(МассивОбъектов, ИспользоватьФаксимиле, ПечатнаяФормаТолькоВРублях, Ошибки)
	//Осипов - подменяем данные объектов по заменам
	Результат = ПродолжитьВызов(МассивОбъектов, ИспользоватьФаксимиле, ПечатнаяФормаТолькоВРублях, Ошибки);
	Если Доп_С.ЭтоПечатьИзВнешнейПечатнойФормойСЗаменами() Тогда
		//Подменяем в таблице запасов
		Для Каждого СтрокаДокумента ИЗ Результат Цикл   
			Сч = 0;
			Для Каждого Строка ИЗ СтрокаДокумента.ТаблицаЗапасы Цикл
				Сч = Сч + 1;
				Строка.ПредставлениеНоменклатуры = "" + Сч;
			КонецЦикла;
		КонецЦикла;
	КонецЕсли;
	Возврат Результат;
КонецФункции

Определяем, наша печатная форма УПДСЗаменами или нет с помощью анализа стека:

Функция ЭтоПечатьИзВнешнейПечатнойФормойСЗаменами() Экспорт
	Попытка
		Ошибка = 1 / 0;  //https://infostart.ru/1c/articles/1879817/
	Исключение
		ПодробноеПредставлениеОшибки = ПодробноеПредставлениеОшибки(ИнформацияОбОшибке());
	КонецПопытки;	
	Возврат Найти(ПодробноеПредставлениеОшибки, "ВнешняяОбработка.УПДСЗаменами");
КонецФункции

В результате имеем то, что нам нужно (названия товаров заменены цифрами):

Красиво, гениально! Для меня лично нет ничего более приятного, чем обманывать 1С, когда удается легко подсунуть ей нужные мне данные. Учитывая, как порой это сложно сделать, ведь 1С любит километровой длины процедуры, плохо изолирует функции и плохо документирует код.

Слава богу, тут 1С передает на печать данные в виде коллекции, которую можно обработать самому и даже сохраняет там ссылки на исходные объекты. Это уже небольшие следы улучшений.

Среда: УНФ 3.0.11.142. Объем: 1.5 час.