Отключение контроля заполнения цен в заказе поставщику УТ 11.4

Клиенту понадобилось отправлять заказы поставщику без цен, попросил отключить контроль цен в заказе поставщику.

С помощью отладчика определил, что контроль цен нужно отключить расширением модуля ЗакупкиСервер:

&Вместо("СообщитьОбОшибкахКонтрольЗаполненияЦен")
Процедура дор_СообщитьОбОшибкахКонтрольЗаполненияЦен(Знач Выборка, Знач ДокументЗакупки, Отказ)
	//У заказа поставщику не контролируем цены
	Если ТипЗнч(ДокументЗакупки) = Тип("ДокументОбъект.ЗаказПоставщику") Тогда
		Возврат;
	КонецЕсли;
	ПродолжитьВызов(Выборка, ДокументЗакупки, Отказ);
КонецПроцедуры

После этого появляется возможность проводить заказ с пустыми ценами:

Печатная форма при этом формируется без цены и суммы:

Осталось еще добавить кнопку для очистки цен, расширяя форму заказа поставщику:

&НаСервере
Процедура дор_ПриСозданииНаСервереПосле(Отказ, СтандартнаяОбработка)
	
	ИмяКоманды = "дор_ОчиститьЦены";
	КомандаФормы = ЭтаФорма.Команды.Добавить(ИмяКоманды);
	КомандаФормы.Действие = ИмяКоманды;
	КомандаФормы.Заголовок = "Очистить цены";
	КомандаФормы.ИзменяетСохраняемыеДанные = ложь;
	КомандаФормы.Отображение = ОтображениеКнопки.Текст;
	
	ЭлементПеред = ЭтаФорма.Элементы.ТоварыСкопироватьСтроки;
	Элемент = ЭтаФорма.Элементы.Вставить(ИмяКоманды, Тип("КнопкаФормы"), ЭлементПеред.Родитель, ЭлементПеред);
	Элемент.Вид = ВидКнопкиФормы.ОбычнаяКнопка;
	Элемент.ИмяКоманды = ИмяКоманды;

КонецПроцедуры

&НаКлиенте
Процедура дор_ОчиститьЦены(Команда) Экспорт
	Для Каждого Строка ИЗ Объект.Товары Цикл
		Строка.Цена = 0;
		Строка.Сумма = 0;
	КонецЦикла;
КонецПроцедуры

Среда: 11.4.13.46 Объем: 0.8 час.