Запрос по поиску дублей телефонов контрагентов

Попросил написать ИИ запрос, он мне его выдал. Правда сперва выдал по регистру сведений и вместе с исполняемым кодом, пришлось уточнять где хранятся данные. Затем еще уУточнил, чтобы сгруппировал по номеру телефона. Получился вот такой:

ВЫБРАТЬ
 КонтрагентыКонтактнаяИнформация.НомерТелефона КАК НомерТелефона,
 КонтрагентыКонтактнаяИнформация.Ссылка КАК Контрагент
ИЗ
 Справочник.Контрагенты.КонтактнаяИнформация КАК КонтрагентыКонтактнаяИнформация
ГДЕ
 КонтрагентыКонтактнаяИнформация.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ТелефонКонтрагента) И НЕ КонтрагентыКонтактнаяИнформация.Ссылка.ПометкаУдаления
 И КонтрагентыКонтактнаяИнформация.НомерТелефона В
  (ВЫБРАТЬ
   ТЧДубли.НомерТелефона КАК НомерТелефона
  ИЗ
   Справочник.Контрагенты.КонтактнаяИнформация КАК ТЧДубли
  ГДЕ
   ТЧДубли.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ТелефонКонтрагента)
   И ТЧДубли.НомерТелефона <> ""
  СГРУППИРОВАТЬ ПО
   ТЧДубли.НомерТелефона
  ИМЕЮЩИЕ
   КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ТЧДубли.Ссылка) > 1)
УПОРЯДОЧИТЬ ПО
 НомерТелефона,
 Контрагент
ИТОГИ ПО
 НомерТелефона

Запросы:

  1. Напиши запрос на 1С для УНФ, который в справочнике контрагентов найдет все дубли контрагентов по телефону
  2. Перепиши запрос, т.к. данные хранятся в ТЧ КонтактнаяИнформация, оставь только текст запроса для консоли
  3. Перепиши запрос, чтобы одинаковые ссылки были сгруппированы через ИТОГИ по номеру телефона

UPD 4 октября 2026: написал обработку по замене дублей. Немного поправил текст запроса, потому что во вложенном запросе не отсекались помеченные на удаление контрагенты.

&НаСервере
Процедура ОбработатьНаСервере()  
	
	Модуль_нобонус_С = ОбщегоНазначения.ОбщийМодуль("нобонус_С");
	
	Запрос = Новый Запрос;
	Запрос.Текст =
	"ВЫБРАТЬ
	|	КонтрагентыКонтактнаяИнформация.НомерТелефона КАК НомерТелефона,
	|	КонтрагентыКонтактнаяИнформация.Ссылка КАК Контрагент
	|ИЗ
	|	Справочник.Контрагенты.КонтактнаяИнформация КАК КонтрагентыКонтактнаяИнформация
	|ГДЕ
	|	КонтрагентыКонтактнаяИнформация.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ТелефонКонтрагента)
	|	И НЕ КонтрагентыКонтактнаяИнформация.Ссылка.ПометкаУдаления
	|	И КонтрагентыКонтактнаяИнформация.НомерТелефона В
	|			(ВЫБРАТЬ
	|				ТЧДубли.НомерТелефона КАК НомерТелефона
	|			ИЗ
	|				Справочник.Контрагенты.КонтактнаяИнформация КАК ТЧДубли
	|			ГДЕ
	|				ТЧДубли.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ТелефонКонтрагента)
	|				И ТЧДубли.НомерТелефона <> """"
	|				И НЕ ТЧДубли.Ссылка.ПометкаУдаления
	|			СГРУППИРОВАТЬ ПО
	|				ТЧДубли.НомерТелефона
	|			ИМЕЮЩИЕ
	|				КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ТЧДубли.Ссылка) > 1)
	|
	|УПОРЯДОЧИТЬ ПО
	|	НомерТелефона,
	|	Контрагент
	|ИТОГИ ПО
	|	НомерТелефона";
	
	РезультатЗапроса = Запрос.Выполнить();
	ВыборкаПоТелефонам = РезультатЗапроса.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);
	
	ВидТелефона = Справочники.ВидыКонтактнойИнформации.ТелефонКонтрагента;
	
	Пока ВыборкаПоТелефонам.Следующий() Цикл
		
		МаксСумма = -1;
		Победитель = Неопределено;
		СписокКонтрагентов = Новый Массив;
		
		ЗаписьЛога = "Телефон: " + ВыборкаПоТелефонам.НомерТелефона;  
 		Сообщить(ЗаписьЛога);

		
		ВыборкаДетали = ВыборкаПоТелефонам.Выбрать();
		Пока ВыборкаДетали.Следующий() Цикл
			
			ТекущийКонтрагент = ВыборкаДетали.Контрагент;
			СписокКонтрагентов.Добавить(ТекущийКонтрагент);
			
			// Определяем контрагента с максимальной суммой выкупа
			ДанныеПродажПоКонтрагенту = Модуль_нобонус_С.ДанныеПродажПоКонтрагенту(ТекущийКонтрагент); 
			ТекущаяСумма = ДанныеПродажПоКонтрагенту.СуммаПродаж;
			ЗаписьЛога = "  контрагент: " + ТекущийКонтрагент + " сумма выкупа: " + ТекущаяСумма;  
			Сообщить(ЗаписьЛога);
			
			
			Если ТекущаяСумма > МаксСумма Тогда
				МаксСумма = ТекущаяСумма;
				Победитель = ТекущийКонтрагент;
			КонецЕсли;
			
		КонецЦикла;
	
		ЗаписьЛога = "  победитель: " + Победитель;  
		Сообщить(ЗаписьЛога);

		
		// Для остальных контрагентов группы очищаем телефон в табличной части и добавляем запись в комментарий
		Для Каждого КонтрагентСсылка Из СписокКонтрагентов Цикл
			
			Если КонтрагентСсылка = Победитель Тогда
				Продолжить;
			КонецЕсли;
			
			ОбъектКонтрагент = КонтрагентСсылка.ПолучитьОбъект();
			БылИзменен = Ложь;
			
			// Поиск и удаление строки с этим номером из ТЧ КонтактнаяИнформация
			//Отбор = Новый Структура("Вид, НомерТелефона", ВидТелефона, ВыборкаПоТелефонам.НомерТелефона);
			Отбор = Новый Структура("Вид", ВидТелефона);
			НайденныеСтроки = ОбъектКонтрагент.КонтактнаяИнформация.НайтиСтроки(Отбор);
			
			Для Каждого СтрокаКИ Из НайденныеСтроки Цикл
				ОбъектКонтрагент.КонтактнаяИнформация.Удалить(СтрокаКИ);
				БылИзменен = Истина;
			КонецЦикла;
			
			Если БылИзменен Тогда
				ЗаписьЛога = "  удален телефон " + ВыборкаПоТелефонам.НомерТелефона + " у контрагента:  " + КонтрагентСсылка + " основной: " + Победитель;  
				Сообщить(ЗаписьЛога);
				
				Если ЗначениеЗаполнено(ОбъектКонтрагент.Комментарий) Тогда
					ОбъектКонтрагент.Комментарий = ОбъектКонтрагент.Комментарий + Символы.ПС + ЗаписьЛога;
				Иначе
					ОбъектКонтрагент.Комментарий = ЗаписьЛога;
				КонецЕсли;
				
				Если Записывать Тогда
					ОбъектКонтрагент.Записать();
				КонецЕсли;
			КонецЕсли;
			
		КонецЦикла;
		
	КонецЦикла;
	
КонецПроцедуры

&НаКлиенте
Процедура Обработать(Команда)
	ОбработатьНаСервере();
КонецПроцедуры

Также добавил код в модуль контрагента для защиты от создани дублей:


&Перед("ПередЗаписью")
Процедура дор_ПередЗаписью(Отказ)
	
	//Проверяем дубли
	Запрос = Новый Запрос;
	Запрос.Текст =
	"ВЫБРАТЬ Первые 1
	| КонтрагентыКонтактнаяИнформация.Ссылка КАК Контрагент
	|ИЗ
	| Справочник.Контрагенты.КонтактнаяИнформация КАК КонтрагентыКонтактнаяИнформация
	|ГДЕ
	| КонтрагентыКонтактнаяИнформация.Вид = ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ТелефонКонтрагента)
	| И КонтрагентыКонтактнаяИнформация.НомерТелефона В (&НомераТелефонов)
	| И КонтрагентыКонтактнаяИнформация.НомерТелефона <> """"
	| И КонтрагентыКонтактнаяИнформация.Ссылка <> &ТекущаяСсылка
	| И НЕ КонтрагентыКонтактнаяИнформация.Ссылка.ПометкаУдаления";
	
	// Собираем все непустые телефоны из ТЧ записываемого объекта
	НомераТелефонов = Новый Массив;
	ОтборКИ = Новый Структура("Вид", Справочники.ВидыКонтактнойИнформации.ТелефонКонтрагента);
	СтрокиТелефонов = ЭтотОбъект.КонтактнаяИнформация.НайтиСтроки(ОтборКИ);
	
	Для Каждого СтрокаКИ Из СтрокиТелефонов Цикл
		Если СокрЛП(СтрокаКИ.НомерТелефона) <> "" Тогда
			НомераТелефонов.Добавить(СтрокаКИ.НомерТелефона);
		КонецЕсли;
	КонецЦикла;
	
	// Если у объекта не заполнено ни одного телефона, проверку делать не нужно
	Если НомераТелефонов.Количество() <> 0 Тогда
		
		Запрос.УстановитьПараметр("НомераТелефонов", НомераТелефонов);
		Запрос.УстановитьПараметр("ТекущаяСсылка", Ссылка);
		
		РезультатЗапроса = Запрос.Выполнить();
		
		Если НЕ РезультатЗапроса.Пустой() Тогда
			Выборка = РезультатЗапроса.Выбрать();
			Выборка.Следующий();
			
			Сообщение = СтрШаблон("Невозможно записать контрагента! Указанный номер телефона уже используется у контрагента: %1", Выборка.Контрагент);
			Сообщить(Сообщение, СтатусСообщения.Важное);
			
			Отказ = Истина;
		КонецЕсли;
	КонецЕсли;
КонецПроцедуры

Среда: УНФ 3.0.13.374

image_pdfimage_print

fixin

Программирую на 1С с 1999 года. В 1С просто Гений. В 2020 году ушел из офиса на вольные хлеба фриланса. Принимаю заказы.

Вам может также понравиться...

комментария 2

  1. Павел:

    Программист стала профессией прошлого, впереди оператор ии

    • «скоро телевидение заменит театр и кино» (С) Москва слезам не верит. Вы слишком ИИ-верун

Добавить комментарий

Ваш адрес email не будет опубликован. Обязательные поля помечены *